add tepsonic

tepsonic-git/PKGBUILD

@@ -0,0 +1,44 @@
+# Maintainer: Evgeniy Alekseev <arcanis.arch at gmail dot com>
+# Contributor: Dan Vratil <vratil at progdansoft dot com>
+
+pkgname=tepsonic-git
+_gitname=tepsonic
+pkgver=0.ea55436
+pkgrel=1
+pkgdesc="A simple, lightweight audio player written in C++ and Qt that supports collections"
+url="https://github.com/danvratil/TepSonic"
+arch=('i686' 'x86_64')
+license=('GPL3')
+depends=('qt5-base' 'phonon-qt5' 'taglib' 'libqxt')
+makedepends=('git' 'cmake' 'qt5-tools')
+source=(${_gitname}::git+https://github.com/danvratil/TepSonic
+        "phonon_include.patch")
+md5sums=('SKIP'
+         '86e6cd941dbb63392653354ba5239072')
+
+pkgver() {
+    cd "${srcdir}/${_gitname}"
+    # dirty hack since it has no stable releases or tags
+    local ver=$(git describe --always | sed 's|-|.|g')
+    printf "0.%s" "${ver}"
+}
+
+prepare() {
+    rm -rf "${srcdir}/build"
+    mkdir "${srcdir}/build"
+
+    patch -p0 -i "phonon_include.patch"
+}
+
+build() {
+    cd "${srcdir}/build"
+    cmake -DCMAKE_INSTALL_PREFIX=/usr ../"${_gitname}"
+    make
+}
+
+package() {
+    cd "${srcdir}/build"
+    make DESTDIR="${pkgdir}" install
+}
+
+

tepsonic-git/phonon_include.patch

@@ -0,0 +1,11 @@
+diff -ruN tepsonic.orig/CMakeLists.txt tepsonic/CMakeLists.txt
+--- tepsonic.orig/CMakeLists.txt	2014-08-18 01:25:57.000000000 +0400
++++ tepsonic/CMakeLists.txt	2014-08-18 01:26:16.303149163 +0400
+@@ -88,6 +88,7 @@
+ 
+ include_directories(${CMAKE_CURRENT_SOURCE_DIR}
+                     ${CMAKE_CURRENT_BINARY_DIR}
++                    ${PHONON_INCLUDE_DIR}
+ )
+ 
+ add_subdirectory(3rdparty)