# Contributor: weirdfox <weirdfox@gmail.com>
# Maintainer: Evgeniy "arcanis" Alekseev <esalexeev@gmail.com>

pkgname=kdeplasma-applets-stdin-svn
pkgver=57
pkgrel=1
_pkgname=plasmoidstdin
_pkgver=0.2
pkgdesc="This plasmoid executes a process and captures its stdout or stderr output stream"
arch=('i686' 'x86_64')
url="http://www.kde-look.org/content/show.php/STDIN+Plasmoid?content=92309"
license=('GPL')
depends=('kdebase-workspace')
makedepends=('automoc4' 'cmake' 'subversion')
source=(${_pkgname}::svn+https://plasmoidstdin.svn.sourceforge.net/svnroot/${_pkgname}/${_pkgver}/trunk)
install=${pkgname}.install
md5sums=('SKIP')

pkgver()
{
  cd "${srcdir}/${_pkgname}"
  local ver=`svnversion`
  printf "%s" "${ver//[[:alpha:]]}"
}

build()
{
  if [[ -d ${srcdir}/build ]]; then
    rm -rf "${srcdir}/build"
  fi
  mkdir "${srcdir}/build"; cd "${srcdir}/build"
  cmake -DCMAKE_INSTALL_PREFIX=`kde4-config --prefix` \
        -DCMAKE_BUILD_TYPE=Release \
        ../${_pkgname}
  make
}

package()
{
  cd "${srcdir}/build"
  make DESTDIR="${pkgdir}" install
}
